Anything Forums

Code: Select all

module Main where

main = putStrLn "Hello, world!"[code]

What do we have here?  

Well, first of all we have to deal with the fact that Haskell code is organized into modules.  Modules allow us to easily reuse code in other programs, and they allow the actual language itself to be relatively simple.  The name of the file should match the name of the module.  Here the module is named "Main".

Next we have the "main" function, the center of activity, as in many other programming languages.  The ease of creating this function shouldn't come as any surprise given the fact that Haskell focuses on functions.

[code]putStrLn "Hello, world!"[code]

Here we simply use the putStrLn function to print a string to the screen on its own line.  The similar putStr function does the same, but doesn't automatically skip to a new line.

[img]http://familygeek.com/haskell/hugs3.png[/img]

[b]Testing the code[/b]

So, how do we run the code in this file?

Well, open up your trusty Command Prompt window and "cd" to the directory where you saved your Main.hs file.

Once you're there, start Hugs by simply typing "hugs" and hitting enter.  Again we're back to:

[img]http://familygeek.com/haskell/hugs.png[/img]

To load the "Main" module we simply:

[code]Prelude> :load Main
Main>[code]

The prompt has changed to indicate we're now in the Main module, rather than the Prelude module.

And to run the main function:

[code]Main> main
Hello, world!

Main>[code]

[b]So, we've seen a little bit of Haskell[/b]

Is it scary?

If you say yes, that's not bad.  New things can be scary.  You'll get over it.

The real question, though, is: where do we go from here?

Well, since Haskell is a functional programming language, I'm thinking it might be good to see some more functions.

[b]Expanding on Hello, world[/b]

Anyone even moderately familiar with my other tutorials will recognize the pattern of starting with a simple hello world program and then expanding upon it.

So, let's create a function "greet" which takes a name and greets that person.

Our Main.hs looked like:

[code]module Main where

main = putStrLn "Hello, world!"[code]

Now we're going to expand it with:

[code]module Main where

main = greet "Bob"

greet name = putStrLn ("Hello, " ++ name ++ "!")[code]

Of course, what if we want just the greeting string?

[code]module Main where

main = greet "Bob"

greet name = putStrLn (greeting name)

greeting name = "Hello, " ++ name ++ "!"[code]

[b]Tidying the code up - Haskell tricks[/b]

Haskell by default infers the types of data being used in a program, but for documentation purposes, we can explicitly specify the types a function uses and returns.

Doing this, we write a type signature for main.  The "main" function does an IO action, and returns the closest thing you can get in Haskell to nothing, so:

[code]module Main where

main :: IO ()
main = greet "Bob"

greet name = putStrLn (greeting name)

greeting name = "Hello, " ++ name ++ "!"[code]

Double colons separate the name of a function and its signature.

Continuing, we generate a signature for the "greet" and "greeting" functions.

[code]module Main where

main :: IO ()
main = greet "Bob"

greet :: String -> IO ()
greet name = putStrLn (greeting name)

greeting :: String -> String
greeting name = "Hello, " ++ name ++ "!"[code]

These signatures are saying, "greet takes a string as an argument and does an IO operation," and, "greeting takes a string as an argument and returns another string."

[code]greet name = putStrLn (greeting name)[code]

Here we use parentheses because otherwise this would be seen as putStrLn taking two arguments, "greeting" and "name".  Since putStrLn only takes one argument, this would clearly be erroneous.

But the parentheses can get annoying, so we have the $ operator.  Essentially, the $ operator takes the value on its right hand side and gives it to the function on the left hand side.  So, now our greet function looks like:

[code]greet name = putStrLn $ greeting name[code]

So, our code now looks like:

[code]module Main where

main :: IO ()
main = greet "Bob"

greet :: String -> IO ()
greet name = putStrLn $ greeting name

greeting :: String -> String
greeting name = "Hello, " ++ name ++ "!"[code]

[b]Input as well as output[/b]

All of this greeting isn't very much good unless we can get input from the user as well, to find out their name.  

IO actions aren't quite like other functions.  To "chain" them together in sequence we use the keyword "do".

[code]module Main where

main :: IO ()
main = do putStr "You are? "
          name <- getLine
          greet name

greet :: String -> IO ()
greet name = putStrLn $ greeting name

greeting :: String -> String
greeting name = "Hello, " ++ name ++ "!"[code]

Probably the most immediately notiecable change is the use of indentation.  Haskell uses what's referred to as "layout", so semi-colons and braces aren't necessary.  They are available:

[code]main = do { putStr "You are? ";
name <- getLine;
greet name }[code]

Of course, the "layout" approach is so much nicer that it'd be silly to use braces and semi-colons.

The second new bit of syntax is:

[code]name <- getLine[code]

The return of getLine is a string, but an IO "tainted" string, which can't be immediately used.  Using the <-  syntax, "name" is a plain old string we can use elsewhere.

[b]Conditionals[/b]

How about when the name given to the greeting function is "Haskell", the greeting is "Hey, whadda ya know?  This is a Haskell program!"

[code]module Main where

main :: IO ()
main = do putStr "You are? "
          name <- getLine
          greet name

greet :: String -> IO ()
greet name = putStrLn $ greeting name

greeting :: String -> String
greeting name = 
  if name == "Haskell"
    then "Hey, whadda ya know?  This is a Haskell program!"
    else "Hello, " ++ name ++ "!"[code]

This should look fairly straightforward to a programmer with basic experience in other languages.  Also, again we use "layout" to signify the structure of the conditional.

[b]Case expressions[/b]

Let's say we want our program to greet "Matz" with, "You make a good language."  Using only "if":

[code]module Main where

main :: IO ()
main = do putStr "You are? "
          name <- getLine
          greet name

greet :: String -> IO ()
greet name = putStrLn $ greeting name

greeting :: String -> String
greeting name = 
  if name == "Haskell"
    then "Hey, whadda ya know?  This is a Haskell program!"
    else if name == "Matz"
           then "You make a good language."
           else "Hello, " ++ name ++ "!"[code]

Wow, that's ugly.  Fortunately, we have the case expression that should look familiar to programmers.

[code]module Main where

main :: IO ()
main = do putStr "You are? "
          name <- getLine
          greet name

greet :: String -> IO ()
greet name = putStrLn $ greeting name

greeting :: String -> String
greeting name = 
  case name of
    "Haskell" -> "Hey, whadda ya know?  This is a Haskell program!"
    "Matz"    -> "You make a good language."
    otherwise -> "Hello, " ++ name ++ "!"[code]

As with "if", we use layout.

[b]Overloading functions[/b]

Of course, we can do this even more cleanly by overloading the greeting function.

[code]module Main where

main :: IO ()
main = do putStr "You are? "
          name <- getLine
          greet name

greet :: String -> IO ()
greet name = putStrLn $ greeting name

greeting :: String -> String
greeting "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
greeting "Matz"    = "You make a good language."
greeting name      = "Hello, " ++ name ++ "!"[code]

[b]Loops[/b]

At this point you might be tempted to ask how Haskell handles looping, since that's a pretty basic thing for programmers to learn about in other languages.

Haskell provides no special syntax for looping.  All looping is achieved via recursion, where a function calls itself.

[code]module Main where

main :: IO ()
main = do putStr "You are? "
          name <- getLine
          if name == "quit"
            then return ()
            else do greet name
                    main

greet :: String -> IO ()
greet name = putStrLn $ greeting name

greeting :: String -> String
greeting "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
greeting "Matz"    = "You make a good language."
greeting name      = "Hello, " ++ name ++ "!"[code]

A few questions that may come up from looking at this:<ul><li>[code]return ()[code]

What does "return" do?  This basically turns () into IO (), which is the return our main function wants.</li><li>Why is "do" repeated in the "if" expression?  The "if" basically interrupts the chain of expressions we were creating.  To start another "chain" we need to use "do" again.</li></ul>
[b]Lists[/b]

So, we can greet a number of people.  Of course, what if we want to be able to get a list of people we've greeted?

Well, we need a list.  A list in Haskell can contain any number of values, as long as they're all the same type.  The most basic list is an empty list:

[code][][code]

A small list of names might look like:

[code]["Bob", "John"][code]

Anything dealing with such structures in other programming languages, where we often use the term "array", should instantly bring to mind loops.  Of course, we've already covered that.  Haskell has no explicit looping syntax, but rather recursion.  The solution, therefore is to find a way to define lists in a recursive manner.

Thankfully, Haskell lists are naturally recursive.  The : operator adds an element to the beginning of a list.  Our name list could look like:

[code]"Bob" : "John" : [][code]

Let's look at this in practice in a simple example.  A simple range function should create a list of numbers from a start to an end.

[code]range s e = if s > e 
              then []
              else s : range (s + 1) e[code]

This could look fairly cryptic until we break a sample use of it down.

[code]range 1 5
1 : range 2 5
1 : 2 : range 3 5
1 : 2 : 3 : range 4 5
1 : 2 : 3 : 4 : range 5 5
1 : 2 : 3 : 4 : 5 : range 6 5
1 : 2 : 3 : 4 : 5 : []
1 : 2 : 3 : 4 : [5]
1 : 2 : 3 : [4, 5]
1 : 2 : [3, 4, 5]
1 : [2, 3, 4, 5]
[1, 2, 3, 4, 5][code]

Seeing a function with two arguments points out an interesting fact about Haskell.  Arguments to a function are simply separated by space, rather than commas, as in many other programming languages.

So, we might as well jump right in.

[code]module Main where

main :: IO [String]
main = do putStr "You are? "
          name <- getLine
          if name == "quit"
            then return []
            else do greet name
                    nextRun <- main
                    return $ name : nextRun


greet :: String -> IO ()
greet name = putStrLn $ greeting name

greeting :: String -> String
greeting "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
greeting "Matz"    = "You make a good language."
greeting name      = "Hello, " ++ name ++ "!"[code]

[b]Breaking it down[/b]

As always, breaking a large complex program down into small, understandable components is essential to understanding.

[code]main :: IO [String][code]

Our new signature for main indicates that it returns a list of strings.  Of course it remains IO "tainted".

[code]return [][code]

As before, if the user enters "quit", then we stop "looping".  This time, though, we return an empty list, much as we did in the range function.

[code]nextRun <- main[code]

We can't directly use main, since it returns an IO tainted list.  Instead we first extract that list.

[code]return $ name : nextRun[code]

Here we add the current name onto the list of names generated by running the main function again, then "return" that list.  It may seem odd, but the last run of the main function is the last to finish.

[b]Another function[/b]

Since this is getting fairly complex, perhaps we should break it into a separate function.

[code]module Main where

main :: IO [String]
main = greetMultiple

greet :: String -> IO ()
greet name = putStrLn $ greeting name

greeting :: String -> String
greeting "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
greeting "Matz"    = "You make a good language."
greeting name      = "Hello, " ++ name ++ "!"

greetMultiple :: IO [String]
greetMultiple = do putStr "You are? "
                   name <- getLine
                   if name == "quit"
                     then return []
                     else do greet name
                             nextRun <- greetMultiple
                             return $ name : nextRun[code]

[b]And another one[/b]
                             
Not a lot has changed, but now we can do something with the list of strings greetMultiple returns.  Let's introduce a new function to print all of the strings in a list.

[code]printAll :: [String] -> IO ()
printAll []     = return ()
printAll (x:xs) = do putStrLn x
                     printAll xs[code]
                     
Here we've overloaded the printAll function so printing an empty list just returns ().  When I want to print an actual list, I use the pattern "(x:xs)".  We've seen the : before.  It's used when we're constructing lists.  So here x is the first element in the list.  The rest of the list is "xs", which can be read as the plural of "x".

Our code now looks like:

[code]module Main where

main :: IO ()
main = do names <- greetMultiple
          putStrLn "I greeted:"
          printAll names

greet :: String -> IO ()
greet name = putStrLn $ greeting name

greeting :: String -> String
greeting "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
greeting "Matz"    = "You make a good language."
greeting name      = "Hello, " ++ name ++ "!"

greetMultiple :: IO [String]
greetMultiple = do putStr "You are? "
                   name <- getLine
                   if name == "quit"
                     then return []
                     else do greet name
                             nextRun <- greetMultiple
                             return $ name : nextRun
                             
printAll :: [String] -> IO ()
printAll []     = return ()
printAll (x:xs) = do putStrLn x
                     printAll xs[code]

[b]There's a simpler way[/b]

The task of applying a function to each element in a list is such a common one, you'd think there would be a function or functions already present to solve this problem.

When we're applying a normal function, we can use "map".  Let's say we want to double each number in a list.

[code]timesTwo x = x * 2

map timesTwo [1,2,3,4][code]

Now, when we're using IO "actions", we can't use map, but rather we use the mapM_ function.

[code]module Main where

main :: IO ()
main = do names <- greetMultiple
          putStrLn "I greeted:"
          mapM_ putStrLn names

greet :: String -> IO ()
greet name = putStrLn $ greeting name

greeting :: String -> String
greeting "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
greeting "Matz"    = "You make a good language."
greeting name      = "Hello, " ++ name ++ "!"

greetMultiple :: IO [String]
greetMultiple = do putStr "You are? "
                   name <- getLine
                   if name == "quit"
                     then return []
                     else do greet name
                             nextRun <- greetMultiple
                             return $ name : nextRun[code]
                             
[b]A different greeting approach[/b]

Now, lets say we first want to gather names from a group and then greet them all.  First we need a gatherNames function.

[code]gatherNames :: IO [String]
gatherNames = do putStr "You are? "
                 name <- getLine
                 if name == "quit"
                   then return []
                   else do otherNames <- gatherNames
                           return $ name : otherNames[code]

Now we can incorporate that into our program and use map to generate the appropriate greetings, then pass the result of that with $ to the "mapM_ putStrLn" we've already seen.

[code]module Main where

main :: IO ()
main = do names <- gatherNames
          mapM_ putStrLn $ map greeting names

greet :: String -> IO ()
greet name = putStrLn $ greeting name

greeting :: String -> String
greeting "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
greeting "Matz"    = "You make a good language."
greeting name      = "Hello, " ++ name ++ "!"
                     
gatherNames :: IO [String]
gatherNames = do putStr "You are? "
                 name <- getLine
                 if name == "quit"
                   then return []
                   else do otherNames <- gatherNames
                           return $ name : otherNames[code]

[b]Back to printAll[/b]

[code]mapM_ putStrLn names[code]

Of course we may look at this and think it's uglier in use than:

[code]printAll names[code]

But previously we've seen that the definition of printAll adds quite a bit of unnecessary code.  So, let's redefine printAll.

[code]printAll :: [String] -> IO ()
printAll names = mapM_ putStrLn names[code]

Much better.  We can improve this further, though.  In Haskell, if we have a function which takes two arguments, and only give it one of those arguments, we get another function which takes the final argument.

This is known as "partial application."  The partial application of functions allows us to easily create new functions based on already existing functions.  The printAll function can be rewritten as:

[code]printAll :: [String] -> IO ()
printAll = mapM_ putStrLn[code]

Similarly we can generate the greetings like so:

[code]greetings :: [String] -> [String]
greetings = map greeting[code]

Now, our code looks like:

[code]module Main where

main :: IO ()
main = do names <- gatherNames
          printAll $ greetings names

greet :: String -> IO ()
greet name = putStrLn $ greeting name

greeting :: String -> String
greeting "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
greeting "Matz"    = "You make a good language."
greeting name      = "Hello, " ++ name ++ "!"

greetMultiple :: IO [String]
greetMultiple = do putStr "You are? "
                   name <- getLine
                   if name == "quit"
                     then return []
                     else do greet name
                             nextRun <- greetMultiple
                             return $ name : nextRun
                     
gatherNames :: IO [String]
gatherNames = do putStr "You are? "
                 name <- getLine
                 if name == "quit"
                   then return []
                   else do otherNames <- gatherNames
                           return $ name : otherNames
                           
printAll :: [String] -> IO ()
printAll = mapM_ putStrLn

greetings :: [String] -> [String]
greetings = map greeting[code]

[b]Combining data[/b]

In many cases, data isn't as simple as just someone's name.  We often want different pieces of data grouped together into a single unit.  In Haskell we accomplish his via tuples.

So, with a name, let's say we want to store an age as well, so our greeting function can come up with greetings based on age as well.  An example tuple, then, might be:

[code]("Bob", 49)[code]

But, first, we need to be able to read an integer from the user.  Since everything read in is in the form of a string, we need a means to extract an integer from a string. The "reads" function steps in.  Now, reads returns something along the lines of:

[code][(Int, String)][code]

As a result we need to get the first element from the array, and the first item from the tuple.  The !! operator and fst function will do these things quite nicely.

So, a basic getAge function might look like:

[code]getAge :: IO Integer         
getAge = do putStr "And you're how old? "
            input <- getLine
            return $ fst $ reads input !! 0[code]
            
There's just one problem with this, and it's a big one.  What if someone gives you bad input?  Well, then reads will gives us am empty list, and that makes "reads input !! 0" cause an error.

We need a way to avoid the error in the first place.  We can do so by adding in a conditional expression which checks to see if the list is empty.  Of course, if it is, we should probably tell the user we didn't get their age, and ask them again.  Recursion will serve us well here.

[code]getAge :: IO Int
getAge = do putStr "And you're how old? "
            input <- getLine
            let parsed = reads input
            if parsed == []
              then do putStrLn "I'm sorry, but could you repeat that?"
                      getAge
              else return $ fst $ parsed !! 0[code]

[b]Taking as step back again[/b]

We want to not only get names, but also their ages.  Where we had a gatherNames function before, let's replace that with a gatherInfo function.

[code]gatherInfo :: IO [(String, Int)]
gatherInfo = do putStr "You are? "
                name <- getLine
                if name == "quit"
                  then return []
                  else do age <- getAge
                          let info = (name,age)
                          otherInfo <- gatherInfo
                          return $ info : otherInfo[code]

The basic form looks pretty much like other recursive functions we've defined.

Now, even though we have a very different type of data here than a simple string, we can get the string from each piece of info with map and fst.

[code]module Main where

main :: IO ()
main = do info <- gatherInfo
          let names = map fst info
          printAll $ greetings names

greeting :: String -> String
greeting "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
greeting "Matz"    = "You make a good language."
greeting name      = "Hello, " ++ name ++ "!"
                           
printAll :: [String] -> IO ()
printAll = mapM_ putStrLn

greetings :: [String] -> [String]
greetings = map greeting
         
getAge :: IO Int
getAge = do putStr "And you're how old? "
            input <- getLine
            let parsed = reads input
            if parsed == []
              then do putStrLn "I'm sorry, but could you repeat that?"
                      getAge
              else return $ fst $ parsed !! 0

gatherInfo :: IO [(String, Int)]
gatherInfo = do putStr "You are? "
                name <- getLine
                if name == "quit"
                  then return []
                  else do age <- getAge
                          let info = (name,age)
                          otherInfo <- gatherInfo
                          return $ info : otherInfo[code]

[b]Doing something with the extra information[/b]

Now we have both name and age info for each of the people we're greeting, and we can still greet people the old way, but that seems to be missing the point of having that extra information in the first place.  So, we want to get different greetings depending on age, as well as name.

So, we'll first want to remake the greeting function.  Our old greeting function looked like:

[code]greeting :: String -> String
greeting "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
greeting "Matz"    = "You make a good language."
greeting name      = "Hello, " ++ name ++ "!"[code]

The first thing we realize will have to change is the signature of this function.

[code]greeting :: (String,Int) -> String[code]

Now, for the rest, if the age is less than twelve, we'll answer with: "Do your parents know where you are, <name>?"  If the age is greater than eighty, we'll answer with: "Do your children know where you are, <name>?"  Otherwise we'll use the same rules we applied in the previous greeting function.

To this end we'll use "guards" to define multiple versions of the function for these different conditions.  The syntax should be fairly obvious.

[code]greeting :: (String,Int) -> String
greeting (name,age) 
  | age < 12          = "Do your parents know where you are, "  ++ name ++ "?"
  | age > 80          = "Do your children know where you are, " ++ name ++ "?"
  | name == "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
  | name == "Matz"    = "You make a good language."
  | otherwise         = "Hello, " ++ name ++ "!"[code]
  
So, our entire program is now:

[code]module Main where

main :: IO ()
main = do info <- gatherInfo
          printAll $ greetings info
          

greet :: (String,Int) -> IO ()
greet name = putStrLn $ greeting name
                     
gatherNames :: IO [String]
gatherNames = do putStr "You are? "
                 name <- getLine
                 if name == "quit"
                   then return []
                   else do otherNames <- gatherNames
                           return $ name : otherNames
                           
printAll :: [String] -> IO ()
printAll = mapM_ putStrLn

greetings :: [(String,Int)] -> [String]
greetings = map greeting
         
getAge :: IO Int
getAge = do putStr "And you're how old? "
            input <- getLine
            let parsed = reads input
            if parsed == []
              then do putStrLn "I'm sorry, but could you repeat that?"
                      getAge
              else return $ fst $ parsed !! 0

gatherInfo :: IO [(String, Int)]
gatherInfo = do putStr "You are? "
                name <- getLine
                if name == "quit"
                  then return []
                  else do age <- getAge
                          let info = (name,age)
                          otherInfo <- gatherInfo
                          return $ info : otherInfo

greeting :: (String,Int) -> String
greeting (name,age) 
  | age < 12          = "Do your parents know where you are, "  ++ name ++ "?"
  | age > 80          = "Do your children know where you are, " ++ name ++ "?"
  | name == "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
  | name == "Matz"    = "You make a good language."
  | otherwise         = "Hello, " ++ name ++ "!"[code]
               
[b]Modules[/b]

So, we've seen input, output, strings, functions, conditionals, lists, tuples, and some very handy functions like map and mapM_.  What's next?

Well, looking at the above program, most of it handles greeting people, and then one lonely function is the main function where everything happens.  What if I want to use the functions related to greeting in another program but I want a different main?  

Well, then I need to put all of those functions into their own module.  Let's call the new module Greeting.  Naturally, it'll be located in the file Greeting.hs.

[code]module Greeting where

greet :: (String,Int) -> IO ()
greet name = putStrLn $ greeting name
                     
gatherNames :: IO [String]
gatherNames = do putStr "You are? "
                 name <- getLine
                 if name == "quit"
                   then return []
                   else do otherNames <- gatherNames
                           return $ name : otherNames
                           
printAll :: [String] -> IO ()
printAll = mapM_ putStrLn

greetings :: [(String,Int)] -> [String]
greetings = map greeting
         
getAge :: IO Int
getAge = do putStr "And you're how old? "
            input <- getLine
            let parsed = reads input
            if parsed == []
              then do putStrLn "I'm sorry, but could you repeat that?"
                      getAge
              else return $ fst $ parsed !! 0

gatherInfo :: IO [(String, Int)]
gatherInfo = do putStr "You are? "
                name <- getLine
                if name == "quit"
                  then return []
                  else do age <- getAge
                          let info = (name,age)
                          otherInfo <- gatherInfo
                          return $ info : otherInfo

greeting :: (String,Int) -> String
greeting (name,age) 
  | age < 12          = "Do your parents know where you are, "  ++ name ++ "?"
  | age > 80          = "Do your children know where you are, " ++ name ++ "?"
  | name == "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
  | name == "Matz"    = "You make a good language."
  | otherwise         = "Hello, " ++ name ++ "!"[code]

No our Main module simply looks like:

[code]module Main where

import Greeting

main :: IO ()
main = do info <- gatherInfo
          printAll $ greetings info[code]
          
Of course, if you want it to be explicit where the functions you're using come from, you can prepend the name of the module.

[code]module Main where

import Greeting

main :: IO ()
main = do info <- Greeting.gatherInfo
          Greeting.printAll $ Greeting.greetings info[code]

This can be encorced by using the "qualified" import modifier.

[code]module Main where

import qualified Greeting

main :: IO ()
main = do info <- Greeting.gatherInfo
          Greeting.printAll $ Greeting.greetings info[code]
          
And with either we can limit the functions we import.

[code]module Main where

import Greeting (gatherInfo, printAll, greetings)

main :: IO ()
main = do info <- gatherInfo
          printAll $ greetings info[code]
          
[b]Introducing our own data types[/b]          
          
Of course, at this point, we've used a new data type in the form of a tuple.  However, we're counting on being able to recognize that a tuple consisting of a string and an integer is a person.

Haskell gives us the power to be more expressive, by introducing new data types.  In this case it's really quite simple.

[code]data PersonInfo = Person String Int[code]

This introduces a new type called PersonInfo with a single constructor which takes a string and an int.  So, let's start by simply redefining the greeting function to take advantage of this new data type.

[code]greeting :: PersonInfo -> String
greeting (Person name age) 
  | age < 12          = "Do your parents know where you are, "  ++ name ++ "?"
  | age > 80          = "Do your children know where you are, " ++ name ++ "?"
  | name == "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
  | name == "Matz"    = "You make a good language."
  | otherwise         = "Hello, " ++ name ++ "!"[code]

And, modifying the rest of our code to use this new data type, we end up with:

[code]module Greeting where
          
data PersonInfo = Person String Int          
          
greet :: PersonInfo -> IO ()
greet p = putStrLn $ greeting p
                           
printAll :: [String] -> IO ()
printAll = mapM_ putStrLn

greetings :: [PersonInfo] -> [String]
greetings = map greeting
         
getAge :: IO Int
getAge = do putStr "And you're how old? "
            input <- getLine
            let parsed = reads input
            if parsed == []
              then do putStrLn "I'm sorry, but could you repeat that?"
                      getAge
              else return $ fst $ parsed !! 0

gatherInfo :: IO [PersonInfo]
gatherInfo = do putStr "You are? "
                name <- getLine
                if name == "quit"
                  then return []
                  else do age <- getAge
                          let info = Person name age
                          otherInfo <- gatherInfo
                          return $ info : otherInfo

greeting :: PersonInfo -> String
greeting (Person name age) 
  | age < 12          = "Do your parents know where you are, "  ++ name ++ "?"
  | age > 80          = "Do your children know where you are, " ++ name ++ "?"
  | name == "Haskell" = "Hey, whadda ya know?  This is a Haskell program!"
  | name == "Matz"    = "You make a good language."
  | otherwise         = "Hello, " ++ name ++ "!"[code]
  
To arrive at this, I made very few changes to the code I had previously.  This should demonstrate quite nicely the expressive power of Haskell.

[b]Greeting other things[/b]

Now, we've defined a set of functions useful for greeting a person.  However, people are not the only things we may want to greet.  Consider, for instance, the case where we want to greet a dog.  For the purposes of our program a dog will be described by its name, build and color.  Based on these things we'll formulate a greeting.

First thing's first, though.  Let's define the data types we'll need.

[code]data Build = Skinny | Medium | Fat
data Color = White | Black | Gray | Red | Brown
data DogInfo = Dog String Build Color[code]

In the build and Color data types, we have a set of constructors which take no arguments.  Any one of these constructors creates a value of type Build or Color.  This is somewhat analogous to the idea of enumerated types or "enums" in other languages.  

The Dog constructor then uses these data types.  

[b]Let's talk about classes[/b]

For the purposes of this document, please foget what you know about classes in object-oriented languages like C++, Java, C#, Python, Ruby, Eiffel, etc.  When we talk about classes in Haskell, we're talking about classifying data types, according to what functions we can use on them.

The advantage of classifying data types in this way is that we don't need to be as specific when declaring a function.  Consider my current declaration of the greeting function.

<!--c1--></div>

[color=#888888][size=85]Archived topic from Iceteks,  old topic ID:2964, old post ID:24219[/size][/color]